chore: Modernize project setup

Update dependencies, move to Gradle KTs and overall improve build and project files.

android/app/build.gradle

@@ -1,114 +0,0 @@
-plugins {
-    id "com.android.application"
-    id "kotlin-android"
-    id "dev.flutter.flutter-gradle-plugin"
-}
-
-def localProperties = new Properties()
-def localPropertiesFile = rootProject.file('local.properties')
-if (localPropertiesFile.exists()) {
-    localPropertiesFile.withReader('UTF-8') { reader ->
-        localProperties.load(reader)
-    }
-}
-
-def flutterVersionCode = localProperties.getProperty('flutter.versionCode')
-if (flutterVersionCode == null) {
-    flutterVersionCode = '1'
-}
-
-def flutterVersionName = localProperties.getProperty('flutter.versionName')
-if (flutterVersionName == null) {
-    flutterVersionName = '1.0'
-}
-
-android {
-    compileSdk 34
-
-    compileOptions {
-        coreLibraryDesugaringEnabled true
-        sourceCompatibility JavaVersion.VERSION_17
-        targetCompatibility JavaVersion.VERSION_17
-    }
-    kotlinOptions {
-        jvmTarget = '17'
-    }
-    sourceSets {
-        main.java.srcDirs += 'src/main/kotlin'
-    }
-    defaultConfig {
-        applicationId "app.revanced.manager.flutter"
-        minSdk 26
-        targetSdk 34
-        versionCode flutterVersionCode.toInteger()
-        versionName flutterVersionName
-    }
-    buildTypes {
-        configureEach {
-            shrinkResources = false
-            minifyEnabled = false
-            signingConfig signingConfigs.debug
-            ndk {
-                abiFilters 'arm64-v8a', 'armeabi-v7a', 'x86_64'
-            }
-        }
-        release {
-            shrinkResources true
-            minifyEnabled true
-            if (System.getenv("signingKey") != null) {
-                signingConfigs {
-                    create("release") {
-                        storeFile = file(System.getenv("signingKey"))
-                        storePassword = System.getenv("keyStorePassword")
-                        keyAlias = System.getenv("keyAlias")
-                        keyPassword = System.getenv("keyPassword")
-                    }
-                }
-                signingConfig = signingConfigs.release
-                resValue "string", "app_name", "ReVanced Manager"
-                applicationVariants.all { variant ->
-                    variant.outputs.all {
-                        outputFileName = "revanced-manager-v${flutterVersionName}.apk"
-                    }
-                }
-            } else {
-                signingConfig = signingConfigs.debug
-                resValue "string", "app_name", "ReVanced Manager (Debug)"
-                applicationIdSuffix ".debug"
-            }
-        }
-        debug {
-            resValue "string", "app_name", "ReVanced Manager (Debug)"
-            applicationIdSuffix ".debug"
-        }
-        profile {
-            resValue "string", "app_name", "ReVanced Manager (Profile)"
-            applicationIdSuffix ".profile"
-        }
-    }
-    packagingOptions {
-        jniLibs {
-            useLegacyPackaging true
-            excludes += ['/prebuilt/**']
-        }
-        resources {
-            excludes += ['/prebuilt/**']
-        }
-    }
-
-    namespace 'app.revanced.manager.flutter'
-}
-
-kotlin {
-    jvmToolchain(17)
-}
-
-flutter {
-    source '../..'
-}
-
-dependencies {
-    coreLibraryDesugaring("com.android.tools:desugar_jdk_libs:2.0.4") // https://pub.dev/packages/flutter_local_notifications#gradle-setup
-    implementation("app.revanced:revanced-patcher:19.3.1")
-    implementation("app.revanced:revanced-library:2.2.1")
-}

android/app/build.gradle.kts

@@ -0,0 +1,91 @@
+plugins {
+    id("com.android.application")
+    id("kotlin-android")
+    // The Flutter Gradle Plugin must be applied after the Android and Kotlin Gradle plugins.
+    id("dev.flutter.flutter-gradle-plugin")
+}
+
+android {
+    namespace = "app.revanced.manager.flutter"
+    compileSdk = 34
+    ndkVersion = "27.0.12077973"
+
+    compileOptions {
+        isCoreLibraryDesugaringEnabled = true
+
+        sourceCompatibility = JavaVersion.VERSION_17
+        targetCompatibility = JavaVersion.VERSION_17
+    }
+
+    kotlinOptions {
+        jvmTarget = JavaVersion.VERSION_17.toString()
+    }
+
+    defaultConfig {
+        applicationId = "app.revanced.manager.flutter"
+        minSdk = 26
+        targetSdk = 34
+        versionCode = flutter.versionCode
+        versionName = flutter.versionName
+    }
+
+    buildTypes {
+        configureEach {
+            isShrinkResources = false
+            isMinifyEnabled = false
+
+            signingConfig = signingConfigs["debug"]
+
+            ndk.abiFilters += setOf("armeabi-v7a", "arm64-v8a", "x86_64")
+        }
+
+        release {
+            isShrinkResources = true
+            isMinifyEnabled = true
+
+            val keystoreFile = file("keystore.jks")
+            if (keystoreFile.exists()) {
+                signingConfig = signingConfigs.create("release") {
+                    storeFile = keystoreFile
+                    storePassword = System.getenv("KEYSTORE_PASSWORD")
+                    keyAlias = System.getenv("KEYSTORE_ENTRY_ALIAS")
+                    keyPassword = System.getenv("KEYSTORE_ENTRY_PASSWORD")
+                }
+            } else {
+                resValue("string", "app_name", "ReVanced Manager (Debug)")
+                applicationIdSuffix = ".debug"
+
+                signingConfig = signingConfigs["debug"]
+            }
+
+            resValue("string", "app_name", "ReVanced Manager")
+        }
+
+        debug {
+            resValue("string", "app_name", "ReVanced Manager (Debug)")
+            applicationIdSuffix = ".debug"
+        }
+    }
+
+    packaging {
+        jniLibs {
+            useLegacyPackaging = true
+            excludes.add("/prebuilt/**")
+        }
+
+        resources {
+            excludes.add("/prebuilt/**")
+        }
+    }
+}
+
+flutter {
+    source = "../.."
+}
+
+dependencies {
+    coreLibraryDesugaring(libs.desugar.jdk.libs) // https://pub.dev/packages/flutter_local_notifications#gradle-setup
+    implementation(libs.revanced.patcher)
+    implementation(libs.revanced.library)
+}
+

android/app/proguard-rules.pro

@@ -1,10 +1,3 @@
-# Add project specific ProGuard rules here.
-# You can control the set of applied configuration files using the
-# proguardFiles setting in build.gradle.kts.kts.
-#
-# For more details, see
-#   http://developer.android.com/guide/developing/tools/proguard.html
-
 -dontobfuscate
 
 -keep class app.revanced.** { *; }

android/app/src/debug/AndroidManifest.xml

@@ -1,3 +1,7 @@
 <manifest xmlns:android="http://schemas.android.com/apk/res/android">
+    <!-- The INTERNET permission is required for development. Specifically,
+         the Flutter tool needs it to communicate with the running application
+         to allow setting breakpoints, to provide hot reload, etc.
+    -->
     <uses-permission android:name="android.permission.INTERNET"/>
 </manifest>

android/app/src/profile/AndroidManifest.xml

@@ -1,3 +1,7 @@
 <manifest xmlns:android="http://schemas.android.com/apk/res/android">
+    <!-- The INTERNET permission is required for development. Specifically,
+         the Flutter tool needs it to communicate with the running application
+         to allow setting breakpoints, to provide hot reload, etc.
+    -->
     <uses-permission android:name="android.permission.INTERNET"/>
 </manifest>